***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar 05, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZX584C18 A K 
.param
+vc0 = 1.546e-12	vc1 = 5.916e-12		vc2 = 1.100		vc3 = 5.893e-12		vc4 = 1.705e-1
+tc1 = 4.061e-2		tc2 = 2.021e-2		tc3 = 5.101e-3		tc4 = 2.021e-3
.func irexp(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 9.044e-14	   n = 1.219		  rs = 3.257e-1
+ibv = 5.0e-3		 nbv = 2.0		  bv = 18
+ikf = 1.608e-1
***** capacitance parameter *****
+cjo = 2.409e-11	   m = 3.340e-1		  vj = 5.890e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.113		 xti = 3
+trs1 = 8.156e-4	trs2 = 7.203e-6		tikf = 1.0e-3
+tbv1 = 7.566e-4	tbv2 = -3.509e-7	
.ends BZX584C18
*$
